#  Copyright (C) 2026 The authors of Py-ChemShell
#
#  This file is part of Py-ChemShell.
#
#  Py-ChemShell is free software: you can redistribute it and/or modify
#  it under the terms of the GNU Lesser General Public License as
#  published by the Free Software Foundation, either version 3 of the
#  License, or (at your option) any later version.
#
#  Py-ChemShell is distributed in the hope that it will be useful,
#  but WITHOUT ANY WARRANTY; without even the implied warranty of
#  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
#  GNU Lesser General Public License for more details.
#
#  You should have received a copy of the GNU Lesser General Public
#  License along with Py-ChemShell.  If not, see
#  <http://www.gnu.org/licenses/>.


# YL June 2026

if(${CMAKE_VERSION} VERSION_GREATER_EQUAL "3.12")
    cmake_policy(SET CMP0074 NEW)
endif()

find_package(Git REQUIRED)

# YL TODO 16/09/2026: the latest release is v0.7.0 now which contains smooth Wigner-Seitz
#                     truncation for periodic second-order electrostatics and change to
#                     tblite_new_gfn1_calculator()
set(TBLITE_DEFAULT_VERSION v0.5.0)
set(TBLITE_NAME tblite-0)

file(MAKE_DIRECTORY ${CHEMSH_BUILD_DIR}/lib/tblite)
set(CHEMSH_TBLITE_LIB_DIR ${CHEMSH_BUILD_DIR}/lib/tblite)
set(CHEMSH_TBLITE_MOD_DIR ${CHEMSH_BUILD_DIR}/modules/tblite)
include_directories(
                    ${CHEMSH_BUILD_DIR}/modules/parallel
                    ${CHEMSH_BUILD_DIR}/modules/dl_py2f)

if("${TBLITE}" STREQUAL "")
    add_library(tblite SHARED tblite.f90 tblite_dummies.f90 ${NOTLINKED})
    target_link_libraries(tblite dl_py2f parallel)
    set_target_properties(tblite PROPERTIES LINK_FLAGS "${CHEMSH_LINK_FLAGS}")
    return()
endif()

if(NOT ${TBLITE} STREQUAL "")
    get_filename_component(TBLITE_ABSOLUTE ${TBLITE} ABSOLUTE)
endif()

if(DEBUG)
    set(TBLITE_CMAKE_OPTIONS "")
else()
    set(TBLITE_CMAKE_OPTIONS --no-warn-unused-cli -Wno-dev)
endif()

if(EXISTS ${TBLITE_ABSOLUTE})
    if(IS_DIRECTORY ${TBLITE_ABSOLUTE})
        set(TBLITE_DIR     ${TBLITE_ABSOLUTE})
    else()
        set(TBLITE_TARBALL  ${TBLITE_ABSOLUTE})
        set(TBLITE_DEST_DIR ${CMAKE_CURRENT_LIST_DIR}/${CHEMSH_ARCH}/src)
        set(TBLITE_DIR      ${TBLITE_DEST_DIR})
        if(${CMAKE_VERSION} VERSION_LESS "3.11")
            include(${CHEMSH_DIR}/chemsh/utils/cmake/fetch_content.cmake)
        else()
            include(FetchContent)
        endif()
        FetchContent_Declare(
            tblite_source
            URL ${TBLITE_TARBALL}
        )
        FetchContent_GetProperties(tblite_source)
        if(NOT tblite_source_POPULATED)
            FetchContent_Populate(
                tblite_source
                URL          ${TBLITE_TARBALL}
                SOURCE_DIR   ${TBLITE_DEST_DIR}
                BINARY_DIR   ${CMAKE_CURRENT_LIST_DIR}/${CHEMSH_ARCH}/build
                SUBBUILD_DIR ${CMAKE_CURRENT_LIST_DIR}/${CHEMSH_ARCH}/subbuild
            )
        endif()
    endif()
    set(TBLITE_SRC_DIR ${TBLITE_DIR})
    set(TBLITE_GIT_REPO  "")

else()
    set(TBLITE_GIT_REPO  "${TBLITE}")
    set(TBLITE_DIR       ${CMAKE_CURRENT_LIST_DIR}/${CHEMSH_ARCH})
    set(TBLITE_BUILD_DIR ${CMAKE_CURRENT_LIST_DIR}/${CHEMSH_ARCH}/build)
    set(TBLITE_SRC_DIR   ${CMAKE_CURRENT_LIST_DIR}/src)
    if(EXISTS ${TBLITE_SRC_DIR}/CMakeLists.txt AND NOT ${TBLITE_RECOMPILE})
        set(TBLITE_GIT_REPO "")
    endif()
endif()

if("${TBLITE_BUILD_DIR}" STREQUAL "")
    set(TBLITE_BUILD_DIR ${TBLITE_DIR}/build)
endif()

set(TBLITE_CMAKE_INSTALL_LIBDIR ${TBLITE_BUILD_DIR})

configure_file(tblite_interface.f90 tblite_interface.f90 COPYONLY)

set(TBLITE_Fortran_FLAGS "-fPIC ${CMAKE_Fortran_FLAGS}")

set(TBLITE_CONFIGURE_COMMAND ${CMAKE_COMMAND} -S ${TBLITE_SRC_DIR} -B ${TBLITE_BUILD_DIR}
                                              -DCMAKE_Fortran_COMPILER:STRING=${CMAKE_Fortran_COMPILER}
                                              -DCMAKE_Fortran_COMPILER_ID:STRING=${CMAKE_Fortran_COMPILER_ID}
                                              -DCMAKE_Fortran_COMPILER_VERSION:STRING=${CMAKE_Fortran_COMPILER_VERSION}
                                              -DCMAKE_C_COMPILER:STRING=${CMAKE_C_COMPILER}
                                              -DCMAKE_C_STANDARD:STRING=17
                                              -DCMAKE_C_EXTENSIONS:BOOL=ON
                                              -DCMAKE_Fortran_FLAGS:STRING=${TBLITE_Fortran_FLAGS}
                                              -DCMAKE_Fortran_FLAGS_DEBUG="-g -O0 -traceback -check all -fpe0 -warn all"
                                              -DCMAKE_INSTALL_LIBDIR:PATH=${TBLITE_CMAKE_INSTALL_LIBDIR}
                                              -DCMAKE_BUILD_TYPE=Release
                                              -DCMAKE_EXPORT_COMPILE_COMMANDS:BOOL=ON
                                              -DBUILD_SHARED_LIBS:BOOL=OFF
                                              -DWITH_TESTS:BOOL=OFF
                                              -DWITH_API:BOOL=ON
                                              -DWITH_OpenMP:BOOL=ON
                                              ${TBLITE_CMAKE_OPTIONS}
                                              )

set(TBLITE_CLEAN_COMMAND "")
set(TBLITE_BUILD_COMMAND ${CMAKE_COMMAND} --build ${TBLITE_BUILD_DIR})

set(TBLITE_LIB_DIRECTORY ${TBLITE_SRC_DIR}/${TBLITE_CMAKE_INSTALL_LIBDIR})
set(TBLITE_INSTALL_LIB_COMMAND ${CMAKE_COMMAND} -E copy ${TBLITE_CMAKE_INSTALL_LIBDIR}/libtblite.a                          ${CHEMSH_TBLITE_LIB_DIR}
                       COMMAND ${CMAKE_COMMAND} -E copy ${TBLITE_CMAKE_INSTALL_LIBDIR}/_deps/mctc-lib-build/libmctc-lib.a   ${CHEMSH_TBLITE_LIB_DIR}
                       COMMAND ${CMAKE_COMMAND} -E copy ${TBLITE_CMAKE_INSTALL_LIBDIR}/_deps/multicharge-build/libmulticharge.a ${CHEMSH_TBLITE_LIB_DIR}
                       COMMAND ${CMAKE_COMMAND} -E copy ${TBLITE_CMAKE_INSTALL_LIBDIR}/_deps/dftd4-build/libdftd4.a         ${CHEMSH_TBLITE_LIB_DIR}
                       COMMAND ${CMAKE_COMMAND} -E copy ${TBLITE_CMAKE_INSTALL_LIBDIR}/_deps/s-dftd3-build/libs-dftd3.a     ${CHEMSH_TBLITE_LIB_DIR}
                       COMMAND ${CMAKE_COMMAND} -E copy ${TBLITE_CMAKE_INSTALL_LIBDIR}/_deps/toml-f-build/libtoml-f.a       ${CHEMSH_TBLITE_LIB_DIR}
)
set(TBLITE_INSTALL_MOD_COMMAND ${CMAKE_COMMAND} -E copy_directory ${TBLITE_CMAKE_INSTALL_LIBDIR}/include ${CHEMSH_TBLITE_MOD_DIR})


if(${TBLITE_RECOMPILE})
    set(TBLITE_RECOMPILE 1)
    file(REMOVE_RECURSE ${CHEMSH_ARCH})
    if(RECOMPILE_WITHOUT_DOWNLOAD)
        set(TBLITE_GIT_REPO "")
    endif()
else()
    if(EXISTS ${CHEMSH_TBLITE_LIB_DIR}/libtblite.a)
        set(TBLITE_RECOMPILE 0)
        set(TBLITE_CLEAN_COMMAND       ${CMAKE_COMMAND} -E cmake_echo_color --switch=$(COLOR) --blue --bold "Found all required static libraries. Skipped cleaning step")
        set(TBLITE_BUILD_COMMAND       ${CMAKE_COMMAND} -E cmake_echo_color --switch=$(COLOR) --blue --bold "Skipped recompile step")
        set(TBLITE_CONFIGURE_COMMAND   ${CMAKE_COMMAND} -E cmake_echo_color --switch=$(COLOR) --blue --bold "Skipped configure step")
        set(TBLITE_INSTALL_MOD_COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --switch=$(COLOR) --blue --bold "")
        message("${BoldRed}TBLITE_RECOMPILE${EndColour} set ${BoldWhite}OFF${EndColour}: will not recompile TBLITE")
    else()
        set(TBLITE_RECOMPILE 1)
        file(REMOVE_RECURSE ${CHEMSH_ARCH}/stamp)
        message("${Green}TBLITE_RECOMPILE${EndColour} set ${BoldWhite}OFF${EndColour} but necessary static libraries missing under ${Yellow}${CHEMSH_TBLITE_LIB_DIR}${EndColour}: TBLITE source code will still be recompiled")
    endif()
endif()

include(ExternalProject)
ExternalProject_Add(
    ${TBLITE_NAME}
    GIT_REPOSITORY      ${TBLITE_GIT_REPO}
    GIT_SHALLOW         0
    GIT_CONFIG          advice.detachedHead=false
    GIT_TAG             ${TBLITE_DEFAULT_VERSION}
    UPDATE_DISCONNECTED 1
    UPDATE_COMMAND      pwd
    PREFIX              ${CHEMSH_ARCH}
    STAMP_DIR           ${CHEMSH_ARCH}/stamp
    TMP_DIR             ${CHEMSH_ARCH}/tmp
    BUILD_ALWAYS        ${TBLITE_RECOMPILE}
    SOURCE_DIR          ${TBLITE_SRC_DIR}
    BINARY_DIR          ${TBLITE_DIR}/build
    CONFIGURE_COMMAND   ""
    BUILD_COMMAND       ${CMAKE_COMMAND} -E cmake_echo_color --switch=$(COLOR) --magenta --bold "Architecture for which '${TBLITE_NAME}' is built: '${CHEMSH_ARCH}'"
    INSTALL_COMMAND     ""
)

ExternalProject_Add_Step(
    ${TBLITE_NAME} TBLITE_CONFIGURE
    COMMENT           "Configuring '${TBLITE_NAME}'..."
    ALWAYS            ${TBLITE_RECOMPILE}
    DEPENDEES         configure
    COMMAND           ${TBLITE_CONFIGURE_COMMAND}
    WORKING_DIRECTORY ${TBLITE_SRC_DIR}
)

ExternalProject_Add_Step(
    ${TBLITE_NAME} TBLITE_BUILD
    COMMENT           "Building static library for '${TBLITE_NAME}'..."
    ALWAYS            ${TBLITE_RECOMPILE}
    DEPENDEES         TBLITE_CONFIGURE
    COMMAND           ${TBLITE_CLEAN_COMMAND} COMMAND ${TBLITE_BUILD_COMMAND}
    WORKING_DIRECTORY ${TBLITE_SRC_DIR}
)

ExternalProject_Add_Step(
    ${TBLITE_NAME} TBLITE_INSTALL
    COMMENT           "Installing static library to ${CHEMSH_TBLITE_LIB_DIR}"
    ALWAYS            1
    DEPENDEES         TBLITE_BUILD
    COMMAND           ${TBLITE_INSTALL_LIB_COMMAND} COMMAND ${TBLITE_INSTALL_MOD_COMMAND}
    WORKING_DIRECTORY ${TBLITE_SRC_DIR}
)


add_library(tblite SHARED tblite.f90 tblite_interface.f90 ${LINKED})

target_include_directories(tblite BEFORE PRIVATE ${TBLITE_SRC_DIR}
                                         PRIVATE ${CHEMSH_TBLITE_MOD_DIR})

add_dependencies(tblite ${TBLITE_NAME} dl_py2f parallel)

set_target_properties(tblite PROPERTIES Fortran_MODULE_DIRECTORY ${CHEMSH_TBLITE_MOD_DIR})

find_package(OpenMP REQUIRED)

if(${CHEMSH_ARCH} STREQUAL "gnu")

    find_package(BLAS REQUIRED)
    find_package(LAPACK REQUIRED)

    target_compile_options(tblite PRIVATE -cpp -fopenmp)
    target_link_libraries(tblite PRIVATE dl_py2f parallel BLAS::BLAS LAPACK::LAPACK)

elseif(${CHEMSH_ARCH} STREQUAL "intel")

    target_compile_options(tblite PRIVATE -fpp -qopenmp -fpscomp logicals)

endif()

target_link_options(tblite PRIVATE "LINKER:--whole-archive")
target_link_options(tblite PRIVATE ${CHEMSH_TBLITE_LIB_DIR}/libtblite.a)
target_link_options(tblite PRIVATE ${CHEMSH_TBLITE_LIB_DIR}/libmctc-lib.a)
target_link_options(tblite PRIVATE ${CHEMSH_TBLITE_LIB_DIR}/libmulticharge.a)
target_link_options(tblite PRIVATE ${CHEMSH_TBLITE_LIB_DIR}/libdftd4.a)
target_link_options(tblite PRIVATE ${CHEMSH_TBLITE_LIB_DIR}/libs-dftd3.a)
target_link_options(tblite PRIVATE ${CHEMSH_TBLITE_LIB_DIR}/libtoml-f.a)
target_link_options(tblite PRIVATE "LINKER:--no-whole-archive")

target_link_libraries(tblite PRIVATE OpenMP::OpenMP_Fortran)

set_target_properties(tblite PROPERTIES LINK_FLAGS "-rdynamic -Wl,--export-dynamic                            \
                                                    -Wl,--version-script=${CMAKE_CURRENT_LIST_DIR}/export.map \
                                                   ")



