#  Copyright (C) 2026 The authors of Py-ChemShell
#
#  This file is part of Py-ChemShell.
#
#  Py-ChemShell is free software: you can redistribute it and/or modify
#  it under the terms of the GNU Lesser General Public License as
#  published by the Free Software Foundation, either version 3 of the
#  License, or (at your option) any later version.
#
#  Py-ChemShell is distributed in the hope that it will be useful,
#  but WITHOUT ANY WARRANTY; without even the implied warranty of
#  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
#  GNU Lesser General Public License for more details.
#
#  You should have received a copy of the GNU Lesser General Public
#  License along with Py-ChemShell.  If not, see
#  <http://www.gnu.org/licenses/>.

# you.lu@stfc.ac.uk
# Jan 2026

if(${CMAKE_VERSION} VERSION_GREATER_EQUAL "3.12")
    cmake_policy(SET CMP0074 NEW)
endif()

set(DFTBPLUS_DEFAULT_VERSION 25.1)
string(REGEX MATCH "^[0-9]+" DFTBPLUS_MAJOR_VERSION ${DFTBPLUS_DEFAULT_VERSION})
set(DFTBPLUS_NAME dftbplus-${DFTBPLUS_MAJOR_VERSION})

file(MAKE_DIRECTORY ${CHEMSH_BUILD_DIR}/lib/dftbplus)
set(CHEMSH_DFTBPLUS_LIB_DIR ${CHEMSH_BUILD_DIR}/lib/dftbplus)
set(CHEMSH_DFTBPLUS_MOD_DIR ${CHEMSH_BUILD_DIR}/modules/dftbplus)

include_directories(${CHEMSH_BUILD_DIR}/modules/parallel
                    ${CHEMSH_BUILD_DIR}/modules/dl_py2f)

if("${DFTBPLUS}" STREQUAL "")
    add_library(dftbplus SHARED dftbplus.f90 dftbplus_dummies.f90 ${NOTLINKED})
    target_link_libraries(dftbplus dl_py2f parallel)
    set_target_properties(dftbplus PROPERTIES
        LINK_FLAGS "-Wl,--version-script=${CMAKE_CURRENT_LIST_DIR}/export.map ${CHEMSH_LINK_FLAGS}")
    return()
endif()

if(NOT ${DFTBPLUS} STREQUAL "")
    get_filename_component(DFTBPLUS_ABSOLUTE ${DFTBPLUS} ABSOLUTE)
endif()

if(DEBUG)
    set(DFTBPLUS_CMAKE_OPTIONS "")
else()
    set(DFTBPLUS_CMAKE_OPTIONS --no-warn-unused-cli -Wno-dev)
endif()

if(EXISTS ${DFTBPLUS_ABSOLUTE})
    if(IS_DIRECTORY ${DFTBPLUS_ABSOLUTE})
        set(DFTBPLUS_DIR ${DFTBPLUS_ABSOLUTE})
    else()
        set(DFTBPLUS_TARBALL  ${DFTBPLUS_ABSOLUTE})
        set(DFTBPLUS_DEST_DIR ${CMAKE_CURRENT_LIST_DIR}/${CHEMSH_ARCH}/src)
        set(DFTBPLUS_DIR      ${DFTBPLUS_DEST_DIR})
        if(${CMAKE_VERSION} VERSION_LESS "3.11")
            include(${CHEMSH_DIR}/chemsh/utils/cmake/fetch_content.cmake)
        else()
            include(FetchContent)
        endif()
        FetchContent_Declare(dftbplus_source URL ${DFTBPLUS_TARBALL})
        FetchContent_GetProperties(dftbplus_source)
        if(NOT dftbplus_source_POPULATED)
            FetchContent_Populate(dftbplus_source
                URL          ${DFTBPLUS_TARBALL}
                SOURCE_DIR   ${DFTBPLUS_DEST_DIR}
                BINARY_DIR   ${CMAKE_CURRENT_LIST_DIR}/${CHEMSH_ARCH}/build
                SUBBUILD_DIR ${CMAKE_CURRENT_LIST_DIR}/${CHEMSH_ARCH}/subbuild)
        endif()
    endif()
    set(DFTBPLUS_SRC_DIR ${DFTBPLUS_DIR})
    set(DFTBPLUS_GIT_REPO "")
else()
    set(DFTBPLUS_GIT_REPO  "${DFTBPLUS}")
    set(DFTBPLUS_DIR       ${CMAKE_CURRENT_LIST_DIR}/${CHEMSH_ARCH})
    set(DFTBPLUS_BUILD_DIR ${CMAKE_CURRENT_LIST_DIR}/${CHEMSH_ARCH}/build)
    set(DFTBPLUS_SRC_DIR   ${CMAKE_CURRENT_LIST_DIR}/src)
    if(EXISTS ${DFTBPLUS_SRC_DIR}/src/dftbp/main.F90 AND NOT ${DFTBPLUS_RECOMPILE})
        set(DFTBPLUS_GIT_REPO "")
    endif()
endif()

set(DFTBPLUS_CMAKE_INSTALL_LIBDIR ${DFTBPLUS_BUILD_DIR})
set(DFTBPLUS_Fortran_FLAGS "-fPIC ${CMAKE_Fortran_FLAGS}")

if(WITH_MPI)
    set(DFTBPLUS_WITH_MPI ON)
    message("${BoldWhite}DFTB+${EndColour} will be built with MPI support")
    if(${CHEMSH_ARCH} STREQUAL "intel")
        set(DFTBPLUS_SCALAPACK_OPTION "")
    else()
        # YL 19/02/2026: ScaLAPACK target is now created at top ChemShell level
        if(NOT TARGET ScaLAPACK::ScaLAPACK)
            message(FATAL_ERROR "ScaLAPACK not found for DFTB+.")
        endif()
        set(DFTBPLUS_SCALAPACK_OPTION -DSCALAPACK_LIBRARY:STRING=${ScaLAPACK_LIBRARY})
    endif()
else()
    set(DFTBPLUS_WITH_MPI OFF)
    set(DFTBPLUS_SCALAPACK_OPTION "")
endif()

find_package(OpenMP REQUIRED)

# YL 19/02/2026: we must disable FindCustomBlas/FindCustomLapack to use cray-libsci
if(${CHEMSH_ARCH} STREQUAL "cpe-gnu")
    set(DFTBPLUS_BLAS_OPTION -DBLAS_LIBRARY=NONE -DLAPACK_LIBRARY=NONE)
else()
    set(DFTBPLUS_BLAS_OPTION "")
endif()

set(DFTBPLUS_CLEAN_COMMAND "")
set(DFTBPLUS_BUILD_COMMAND ${CMAKE_COMMAND} --build ${DFTBPLUS_BUILD_DIR} -- -j ${CHEMSH_MAKE_NJOBS})

if(${DFTBPLUS_RECOMPILE})
    set(DFTBPLUS_RECOMPILE 1)
    file(REMOVE_RECURSE ${CHEMSH_ARCH})
    if(RECOMPILE_WITHOUT_DOWNLOAD)
        set(DFTBPLUS_GIT_REPO "")
    endif()
else()
    if(EXISTS ${CHEMSH_DFTBPLUS_LIB_DIR}/libdftbplus.a)
        set(DFTBPLUS_RECOMPILE 0)
        set(DFTBPLUS_CLEAN_COMMAND     ${CMAKE_COMMAND} -E cmake_echo_color --switch=$(COLOR) --blue --bold "Found all required static libraries. Skipped cleaning step")
        set(DFTBPLUS_BUILD_COMMAND     ${CMAKE_COMMAND} -E cmake_echo_color --switch=$(COLOR) --blue --bold "Skipped recompile step")
        set(DFTBPLUS_CONFIGURE_COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --switch=$(COLOR) --blue --bold "Skipped configure step")
        set(DFTBPLUS_INSTALL_LIB_COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --switch=$(COLOR) --blue --bold "")
        message("${BoldRed}DFTBPLUS_RECOMPILE${EndColour} set ${BoldWhite}OFF${EndColour}: will not recompile DFTB+")
    else()
        set(DFTBPLUS_RECOMPILE 1)
        file(REMOVE_RECURSE ${CHEMSH_ARCH}/stamp)
        message("${Green}DFTBPLUS_RECOMPILE${EndColour} set ${BoldWhite}OFF${EndColour} but necessary static libraries missing under ${Yellow}${CHEMSH_DFTBPLUS_LIB_DIR}${EndColour}: DFTB+ source code will still be recompiled")
    endif()
endif()

# YL NOTE 04/02/2026: DFTB+ uses its own viariable names CMAKE_POSITION_INDEPENDENT_CODE, Fortran_FLAGS_RELEASE, and C_FLAGS_RELEASE
# YL WARNING 04/02/2026: do not directly use "-O2 -fPIC"! (old CMake doesn't accept it)
set(DFTBPLUS_CONFIGURE_COMMAND
    ${CMAKE_COMMAND} -S ${DFTBPLUS_SRC_DIR} -B ${DFTBPLUS_BUILD_DIR}
    -DCMAKE_Fortran_COMPILER:STRING=${CMAKE_Fortran_COMPILER}
    -DCMAKE_C_COMPILER:STRING=${CMAKE_C_COMPILER}
    -DCMAKE_Fortran_FLAGS:STRING=${DFTBPLUS_Fortran_FLAGS}
    -DCMAKE_POSITION_INDEPENDENT_CODE:BOOL=ON
    -DFortran_FLAGS_RELEASE:STRING=-O2\ -fPIC
    -DC_FLAGS_RELEASE:STRING=-O2\ -fPIC
    -DCMAKE_BUILD_TYPE=Release
    -DCMAKE_INSTALL_PREFIX:PATH=${DFTBPLUS_BUILD_DIR}/install
    -DWITH_API:BOOL=ON
    -DWITH_OMP:BOOL=ON
    -DWITH_MPI:BOOL=${DFTBPLUS_WITH_MPI}
    -DBUILD_SHARED_LIBS:BOOL=OFF
    -DINSTANCE_SAFE_BUILD:BOOL=ON
    -DWITH_TBLITE:BOOL=OFF
    -DWITH_SDFTD3:BOOL=OFF
    -DWITH_MBD:BOOL=ON
    -DWITH_TRANSPORT:BOOL=OFF
    -DWITH_ARPACK:BOOL=OFF
    -DWITH_PLUMED:BOOL=OFF
    -DWITH_CHIMES:BOOL=OFF
    ${DFTBPLUS_SCALAPACK_OPTION}
    ${DFTBPLUS_BLAS_OPTION}
    ${DFTBPLUS_CMAKE_OPTIONS})

set(DFTBPLUS_INSTALL_LIB_COMMAND ${CMAKE_COMMAND} -E copy ${DFTBPLUS_BUILD_DIR}/src/dftbp/libdftbplus.a ${CHEMSH_DFTBPLUS_LIB_DIR})
set(DFTBPLUS_INSTALL_MOD_COMMAND ${CMAKE_COMMAND} -E copy_directory ${DFTBPLUS_BUILD_DIR}/src/dftbp/include ${CHEMSH_DFTBPLUS_MOD_DIR})

include(ExternalProject)

ExternalProject_Add(${DFTBPLUS_NAME}
    GIT_REPOSITORY      ${DFTBPLUS_GIT_REPO}
    GIT_SHALLOW         0
    GIT_PROGRESS        ${DEBUG}
    GIT_CONFIG          advice.detachedHead=false
    GIT_TAG             ${DFTBPLUS_DEFAULT_VERSION}
    UPDATE_DISCONNECTED 1
    UPDATE_COMMAND      pwd
    PREFIX              ${CHEMSH_ARCH}
    STAMP_DIR           ${CHEMSH_ARCH}/stamp
    TMP_DIR             ${CHEMSH_ARCH}/tmp
    BUILD_ALWAYS        ${DFTBPLUS_RECOMPILE}
    SOURCE_DIR          ${DFTBPLUS_SRC_DIR}
    BINARY_DIR          ${DFTBPLUS_BUILD_DIR}
    CONFIGURE_COMMAND   ${CMAKE_COMMAND} -E cmake_echo_color --switch=$(COLOR) --white --bold "DFTB+ source will be downloaded to ${DFTBPLUS_SRC_DIR}"
    BUILD_COMMAND       ${CMAKE_COMMAND} -E cmake_echo_color --switch=$(COLOR) --magenta --bold "Architecture for which '${DFTBPLUS_NAME}' is built: '${CHEMSH_ARCH}'"
    INSTALL_COMMAND     "")

# YL 22/02/2026: cherry-picked from the Maitrayee branch (533-spectro-workflow)
# YL 07/02/2026: we need to patch to run taskfarmed jobs, see
#                https://github.com/dftbplus/scalapackfx/issues/47
# YL 09/03/2026: there is a bug in mpienv that nodeComm is never freed and causes MPI context ID overflown upper limit 2^16, see
#                https://github.com/dftbplus/dftbplus/issues/1809
ExternalProject_Add_Step(${DFTBPLUS_NAME} DFTBPLUS_PATCH
    COMMENT           "Applying patches to '${DFTBPLUS_NAME}'..."
    DEPENDEES         configure
    COMMAND           git apply --ignore-whitespace ${CMAKE_CURRENT_LIST_DIR}/hack/blacsenv.patch || true
    COMMAND           git apply --ignore-whitespace ${CMAKE_CURRENT_LIST_DIR}/hack/mpienv.patch || true
    COMMAND           git -C external/scalapackfx/origin apply --ignore-whitespace ${CMAKE_CURRENT_LIST_DIR}/hack/scalapackfx.patch || true
    WORKING_DIRECTORY ${DFTBPLUS_SRC_DIR})

ExternalProject_Add_Step(${DFTBPLUS_NAME} DFTBPLUS_CONFIGURE
    COMMENT           "Configuring '${DFTBPLUS_NAME}'..."
    ALWAYS            ${DFTBPLUS_RECOMPILE}
    DEPENDEES         DFTBPLUS_PATCH
    COMMAND           ${DFTBPLUS_CONFIGURE_COMMAND}
    WORKING_DIRECTORY ${DFTBPLUS_SRC_DIR})

ExternalProject_Add_Step(${DFTBPLUS_NAME} DFTBPLUS_BUILD
    COMMENT           "Building static library for '${DFTBPLUS_NAME}'..."
    ALWAYS            ${DFTBPLUS_RECOMPILE}
    DEPENDEES         DFTBPLUS_CONFIGURE
    COMMAND           ${DFTBPLUS_CLEAN_COMMAND} COMMAND ${DFTBPLUS_BUILD_COMMAND}
    WORKING_DIRECTORY ${DFTBPLUS_SRC_DIR})

ExternalProject_Add_Step(${DFTBPLUS_NAME} DFTBPLUS_INSTALL
    COMMENT           "Installing static library to ${CHEMSH_DFTBPLUS_LIB_DIR}"
    ALWAYS            1
    DEPENDEES         DFTBPLUS_BUILD
    COMMAND           ${DFTBPLUS_INSTALL_LIB_COMMAND} COMMAND ${DFTBPLUS_INSTALL_MOD_COMMAND}
    WORKING_DIRECTORY ${DFTBPLUS_SRC_DIR})

add_library(dftbplus SHARED dftbplus.f90 ${LINKED})

add_dependencies(dftbplus ${DFTBPLUS_NAME} dl_py2f parallel)

target_include_directories(dftbplus BEFORE PRIVATE ${DFTBPLUS_SRC_DIR}
                                           PRIVATE ${CHEMSH_DFTBPLUS_MOD_DIR})

set_target_properties(dftbplus PROPERTIES Fortran_MODULE_DIRECTORY ${CHEMSH_DFTBPLUS_MOD_DIR})
set_target_properties(dftbplus PROPERTIES LINK_FLAGS "-rdynamic \
                                                      -Wl,--export-dynamic \
                                                      -Wl,--version-script=${CMAKE_CURRENT_LIST_DIR}/export.map \
                                                      ${CHEMSH_LINK_FLAGS}")

target_link_options(dftbplus PRIVATE "LINKER:--whole-archive")
target_link_options(dftbplus PRIVATE ${CHEMSH_DFTBPLUS_LIB_DIR}/libdftbplus.a)
target_link_options(dftbplus PRIVATE ${DFTBPLUS_BUILD_DIR}/external/mbd/origin/src/libmbd.a)
if(WITH_MPI)
    target_link_options(dftbplus PRIVATE ${DFTBPLUS_BUILD_DIR}/external/mpifx/origin/lib/libmpifx.a)
    target_link_options(dftbplus PRIVATE ${DFTBPLUS_BUILD_DIR}/external/scalapackfx/origin/lib/libscalapackfx.a)
endif()
target_link_options(dftbplus PRIVATE "LINKER:--no-whole-archive")

if(${CHEMSH_ARCH} STREQUAL "cpe-gnu")
    # YL 19/02/2026: use cray-libsci
    target_compile_options(dftbplus PRIVATE -fopenmp)
    target_link_libraries(dftbplus PRIVATE dl_py2f parallel)
elseif(${CHEMSH_ARCH} STREQUAL "gnu")
    find_package(BLAS REQUIRED)
    find_package(LAPACK REQUIRED)
    target_compile_options(dftbplus PRIVATE -fopenmp)
    target_link_libraries(dftbplus PRIVATE dl_py2f parallel BLAS::BLAS LAPACK::LAPACK)
elseif(${CHEMSH_ARCH} STREQUAL "intel")
    target_compile_options(dftbplus PRIVATE -qopenmp)
    target_link_libraries(dftbplus PRIVATE dl_py2f parallel)
endif()

if(WITH_MPI)
    target_link_libraries(dftbplus PRIVATE ScaLAPACK::ScaLAPACK)
endif()

target_link_libraries(dftbplus PRIVATE OpenMP::OpenMP_Fortran)

set(SKF_SETS
    "mio-1-1|mio|v1.1.0|mio-1-1.tar.xz|C-C.skf"
    "3ob-3-1|3ob|v3.1.0|3ob-3-1.tar.xz|C-C.skf"
    "matsci-0-3|matsci|v0.3.0|matsci-0-3.tar.xz|Si-Si.skf")
set(SKF_DIR ${CMAKE_CURRENT_LIST_DIR}/skf)

if(${CMAKE_VERSION} VERSION_LESS "3.11")
    include(${CHEMSH_DIR}/chemsh/utils/cmake/fetch_content.cmake)
else()
    include(FetchContent)
endif()

foreach(SKF_SET ${SKF_SETS})
    string(REPLACE "|" ";" SKF_TOKENS ${SKF_SET})
    list(GET SKF_TOKENS 0 SKF_NAME)
    list(GET SKF_TOKENS 1 SKF_REPO)
    list(GET SKF_TOKENS 2 SKF_VERSION)
    list(GET SKF_TOKENS 3 SKF_TARBALL)
    list(GET SKF_TOKENS 4 SKF_CHECK)
    set(SKF_URL "https://github.com/dftbparams/${SKF_REPO}/releases/download/${SKF_VERSION}/${SKF_TARBALL}")
    set(SKF_DEST ${SKF_DIR}/${SKF_NAME})
    if(NOT EXISTS ${SKF_DEST}/${SKF_CHECK})
        message("Downloading ${BoldWhite}Slater-Koster files (${SKF_NAME})${EndColour} from ${SKF_URL}")
        file(MAKE_DIRECTORY ${SKF_DIR})
        FetchContent_Declare(skf_${SKF_REPO} URL ${SKF_URL})
        FetchContent_Populate(skf_${SKF_REPO} URL          ${SKF_URL}
                                              SOURCE_DIR   ${SKF_DEST}
                                              BINARY_DIR   ${SKF_DIR}/_build
                                              SUBBUILD_DIR ${SKF_DIR}/_subbuild)
        message("${Green}Slater-Koster files (${SKF_NAME})${EndColour} installed to ${SKF_DEST}")
    else()
        message("${Green}Slater-Koster files (${SKF_NAME})${EndColour} already installed under ${SKF_DEST}")
    endif()
endforeach()

# SKF sets PTBP (https://doi.org/10.1021/acs.jctc.4c00228) and QUASINANO (https://doi.org/10.1021/acs.jctc.5b00702)
set(ZENODO_URL "https://zenodo.org/records/14289468/files/ParameterSets.zip")
set(PTBP_DEST ${SKF_DIR}/ptbp)
set(QUASINANO_DEST ${SKF_DIR}/quasinano)

if(NOT EXISTS ${PTBP_DEST}/Si-Si.skf OR NOT EXISTS ${QUASINANO_DEST}/Si-Si.skf)
    set(ZENODO_WORKDIR ${SKF_DIR}/_build/zenodo)
    file(MAKE_DIRECTORY ${ZENODO_WORKDIR})

    set(ZENODO_ARCHIVE ${ZENODO_WORKDIR}/ParameterSets.zip)
    if(NOT EXISTS ${ZENODO_ARCHIVE})
        message("Downloading ${BoldWhite}PTBP and QUASINANO Slater-Koster files${EndColour} from Zenodo (1.2 GB)...")
        file(DOWNLOAD ${ZENODO_URL} ${ZENODO_ARCHIVE} SHOW_PROGRESS STATUS DL_STATUS)
        list(GET DL_STATUS 0 DL_ERROR)
        if(DL_ERROR)
            message("WARNING: Failed to download ${ZENODO_URL}!")
        endif()
    endif()

    if(EXISTS ${ZENODO_ARCHIVE})
        # extract outer zip to get inner ptbp.zip and qn_rep_skf.zip
        execute_process(COMMAND ${CMAKE_COMMAND} -E tar xf ${ZENODO_ARCHIVE}
                        WORKING_DIRECTORY ${ZENODO_WORKDIR})

        # PTBP: extract ptbp.zip -> complete_set/ -> rename to ptbp/
        if(NOT EXISTS ${PTBP_DEST}/Si-Si.skf)
            message("Installing ${BoldWhite}PTBP${EndColour} Slater-Koster files...")
            execute_process(COMMAND ${CMAKE_COMMAND} -E tar xf ${ZENODO_WORKDIR}/ptbp.zip
                            WORKING_DIRECTORY ${ZENODO_WORKDIR})
            file(RENAME ${ZENODO_WORKDIR}/complete_set ${PTBP_DEST})
            message("${Green}PTBP${EndColour} installed to ${PTBP_DEST}")
        endif()

        # QUASINANO: extract qn_rep_skf.zip -> qn_rep_skfs/ -> rename to quasinano/
        if(NOT EXISTS ${QUASINANO_DEST}/Si-Si.skf)
            message("Installing ${BoldWhite}QUASINANO${EndColour} Slater-Koster files...")
            execute_process(COMMAND ${CMAKE_COMMAND} -E tar xf ${ZENODO_WORKDIR}/qn_rep_skf.zip
                            WORKING_DIRECTORY ${ZENODO_WORKDIR})
            file(RENAME ${ZENODO_WORKDIR}/qn_rep_skfs ${QUASINANO_DEST})
            message("${Green}QUASINANO${EndColour} installed to ${QUASINANO_DEST}")
        endif()
    endif()
else()
    if(EXISTS ${PTBP_DEST}/Si-Si.skf)
        message("${Green}Slater-Koster files (ptbp)${EndColour} already installed under ${PTBP_DEST}")
    endif()
    if(EXISTS ${QUASINANO_DEST}/Si-Si.skf)
        message("${Green}Slater-Koster files (quasinano)${EndColour} already installed under ${QUASINANO_DEST}")
    endif()
endif()

configure_file(${CMAKE_CURRENT_LIST_DIR}/skf_path.py.in ${CMAKE_CURRENT_LIST_DIR}/skf_path.py @ONLY)

set_directory_properties(PROPERTIES
    ADDITIONAL_MAKE_CLEAN_FILES "src;skf;${CMAKE_CURRENT_LIST_DIR}/${CHEMSH_ARCH};${CMAKE_CURRENT_LIST_DIR}/src;"
)
