* Here is the charmm input file
*
bomblevel 0
!wrnlev 0
!prnlev 5

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

! Read in topology file
Open read unit 1 card name "top_all22_prot.inp"
Read rtf card unit 1
close unit 1

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

! Read in another topology file for the ligand as generated by Quanta
open read unit 25 card name "half_pgh.rtf"
read rtf card append unit 25
close unit 25

! Read in parameter file
Open read unit 1 card name "par_mod.inp"
Read para card unit 1
close unit 1

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

! Read in  residue information
open read unit 40 card name "half_pgh.pdb"
read sequence pdb resi unit 40
! Generate segment and set up the internal coordinate table
generate PGH setup
! Rewind the crd file for reading the coordinates
rewind unit 40
! Read in coordinates from the card file
read coor pdb  resi unit 40
close unit 40

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
 
! Read in residue sequence
open read unit 10 card name "half_tim.pdb"
read sequence pdb resi unit 10
! Generate segment HALF and set up the internal coordinate table
generate TIM setup
! Rewind the pdb file for reading the coordinates
rewind unit 10
! Rename resolves IUPAC/CHARMM naming convention
rename atom cd1 sele segid TIM .and. resn ile .and. type cd end
! Read in  coordinates from the pdb file
read coor pdb resi unit 10
close unit 10
rename atom cd  sele segid TIM .and. resn ile .and. type cd1 end

patch glup TIM 165 setup


! Try these lines to verify coordinates - H atoms NOT correct! 

! Read in crystal water
open read unit 12 card name "half_h2o.pdb"
read sequence pdb resi unit 12
! Generate segment SOLV and set up the internal coordinate table - 
! for tip3 using noangle nodihedral see topology-file
generate SOLV noangle nodihedral setup 
! Rewind the pdb file for reading the coordinates
rewind unit 12
! Read in coordinates from the pdb file
read coor pdb resi unit 12
close unit 12


! It is not necessary to use this command if the pdb file includes all 
! hydrogen, but it will better  position the H atoms.  
! If there is no experimental basis for your H positions then use hbuild
! hbuild sele hydrogen end

! The following commands are used to generate missing coordinates 
! (if it is necessary)
ic fill preserve
ic parameters
ic build

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

! define junk sele segid HALF .and. .not. init show end 


open read unit 12 card name "half_pgh_min.pdb"
read coor pdb resi unit 12
close unit 12


!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
! Punch out the PDB
open write unit 14 card name "half_pgh_test.pdb"
write coor pdb unit 14
* This is the PDB for half the structure of TIM with PGH
*
close unit 14 


!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
! Punch out the PSF
! A valid Charmm * title must follow all write commands.
open write unit 14 card name "half_pgh.psf"
write psf card unit 14
* This is the PSF for half the structure of TIM with PGH
*
close unit 14 
 
skip urey

! needed for comparison with dl_poly (also need large cutoff)
nbonds swit cutnb 100.01 ctonnb 99.99 ctofnb 100

energy